先看一下DS的技能說明：
持續時間內依指定對象目前剩餘的HP和SP而變化ATK或MATK

剩餘HP偶數時：ATK+(指定對象Base等級/3)+(技能等級x20)
剩餘HP奇數時：ATK-(指定對象Base等級/3)+(技能等級x20)
剩餘SP偶數時：MATK+(指定對象Base等級/3)+(技能等級x20)
剩餘SP奇數時：MATK-(指定對象Base等級/3)+(技能等級x20)

所以使用變形的上弦月的時機是十分重要，如果在奇數時使用會有反效果，甚至比沒有使用更差。

不知道奇數跟偶數是什麼? 很簡單
奇數為1,3,5,7..
偶數為2,4,6,8..

巨集使用條件及注意事項:

• openkore版本己支援日月影忍者。 就是不會把日月影忍者當成怪物來追殺！
• 只對月影忍者(女)有效
• 建議變形的上弦月等級3或以上才使用
• 建議在第16個夜晚狀態下才使用，因為詠唱比較快，HP,SP回復變化比較少。成功率就比較高！
• 如果巨集中的第16個夜晚狀態，變形的上弦月狀態字眼跟你的版本有出入，請自行修改。
• 看個人需要修改第4,9行

以下巨集是以剩餘HP，SP同時為偶數作為觸發，如果只要其一請自行修改第10行。

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15

automacro zangetsu {
  class Oboro
  sp > 100
  aggressives < 1
  status 第16個夜晚狀態
  status not 動作延遲
  status not 明鏡止水狀態
  status not 變形的上弦月狀態
  location man_fild02
  eval ($::char->{'hp'} == int($::char->{'hp'} / 2) * 2 && $::char->{'sp'} == int($::char->{'sp'} / 2) * 2)
  call {
  log HP:$.hp SP:$.sp;do ss 3026
  }
  timeout 30
}

成功觸發後openkore會顯示如下

    [macro] automacro zangetsu triggered.
    [macro log] HP:9828 SP:758
    You are casting 變形的上弦月 on yourself (Delay: 737ms)
    You use 變形的上弦月 (Lv: 5) on yourself (Delay: 520ms)
    You are now: 變形的上弦月狀態 (Duration: 120s)
    You use 變形的上弦月 on yourself (Lv: 5)
    You are now: 變形的上弦月技能延遲 (Duration: 30s)
    You are now: 動作延遲 (Duration: 1s)

本巨集完全由automacro觸發，並無須修改其他檔案。

簡單說明一下運作，當在指定地圖時沒被怪打，後ATK低過某數值就會觸發。 假設你用正使在用長角槍ATK是150，裝備薔薇鋼盾(DEF130)盾咒成功後後ATK會變成150+130=280。 那觸發數值設280跟150之間就可以。

巨集使用條件及注意事項:

• 最少已學習了盾咒LV1
• 身上帶有薔薇鋼盾 [1]並在items_control.txt設不存倉
• 身上帶有其他盾(盾咒後換用，看個人需要)
• 看個人需要修改第8,9,17行

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19

automacro shieldspell {
  class Royal Guard
  hp > 1
  sp > 50
  status not 卸除盾牌狀態
  status not 盾咒技能延遲
  status not 動作延遲
  eval $::char->{'attack_bonus'} < 180       # 數值設280跟150之間就可以
  location man_fild01,man_fild02              # 觸發地圖
  inventory "薔薇鋼盾 [1]" > 0
  aggressives < 1
  exclusive 1
  call {
  do eq @inventory(薔薇鋼盾 [1])
  do ss 2315 1
  pause 3
  do eq @inventory(巴基力亞鋼盾 [突變蛙卡片] [1])  # 如果不需要轉盾可刪除
  }
}

本教學可以對多個以上的openkore同時下達指令，並且支援所有openkore的Console Command。 我分別寫了partycmd同guildcmd兩個automacro。其實如果利用console作觸發只需一個automacro就可以，寫法如下。

1
2
3
4
5
6
7
8

automacro cmd {
  console /\[(隊伍|公會)\] (.*) \: cmd (.*)/   # 任何人在隊伍或公會頻道中以cmd開始的字串時觸發巨集
  exclusive 1
  call {
  $cmd = $.lastMatch3
  do $cmd
  }
}

但我不建議使用，因為並不安全，如果別人利用密頻對你說[隊伍] 別人 : cmd xxx也會被觸發。如果你正在用console就要考慮一下要不要繼續用。

1
2
3
4
5
6
7
8

automacro partycmd {
  party /cmd (.*)/         # 隊伍頻道中有cmd字串時觸發巨集
  exclusive 1
  call {
  $cmd = $.lastMatch1         # 把cmd後的指令串代入$cmd中
  do $cmd                      # 執行指令串
  }
}

以上是利用隊伍頻道送出同步指令的巨集

巨集使用條件及注意事項:

• 只要同一隊伍即可。
• 最多支持12人。
• 所有隊伍成員也會看到指令，還可以對你的openkore下達任何指令。

使用方法:
e.g. move prontera 移動到中央
openkore: p cmd move prontera
官方遊戲程式: 在隊伍頻道直接輸入cmd move prontera + Enter或在公開頻道輸入cmd move prontera + Ctrl+P

1
2
3
4
5
6
7
8

automacro guildcmd {
  guild /cmd (.*)/         # 公會頻道中有cmd字串時觸發巨集
  exclusive 1
  call {
  $cmd = $.lastMatch1         # 把cmd後的指令串代入$cmd中
  do $cmd                      # 執行指令串
  }
}

以上是利用公會頻道送出同步指令的巨集

巨集使用條件及注意事項:

• 不需要同一隊伍，只需同一公會即可。
• 最多支持50人，看公會擴充組合體制等級而定。
• 所有公會成員也會看到指令，還可以對你的openkore下達任何指令。

使用方法：
e.g. autostorage 自動存倉
openkore: g cmd autostorage
官方遊戲程式: 在公會頻道直接輸入cmd autostorage + Enter或在公開頻道輸入cmd autostorage + Ctrl+G

最後建議把party，guild後的觸發字串cmd改成其他字串，並不要讓人知道。最安全做法是自創隊伍跟公會！